guix-data-service/scripts/guix-data-service-process-jobs.in

#!@GUILE@ --no-auto-compile
-*- scheme -*-
-*- geiser-scheme-implementation: guile -*-
!#
;;; Guix Data Service -- Information about Guix over time
;;; Copyright © 2016, 2017 Ricardo Wurmus <rekado@elephly.net>
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;; Copyright © 2019 Christopher Baines <mail@cbaines.net>
;;;
;;; This file is part of guix-data-service.
;;;
;;; guix-data-service is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; guix-data-service is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with the guix-data-service.  If not, see <http://www.gnu.org/licenses/>.

(use-modules (srfi srfi-1)
             (srfi srfi-37)
             (ice-9 match)
             (knots)
             (guix-data-service database)
             (guix-data-service jobs))

(setvbuf (current-output-port) 'line)
(setvbuf (current-error-port) 'line)

(define %options
  ;; Specifications of the command-line options
  (list (option '("max-processes") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'max-processes
                              (string->number arg)
                              result)))
        (option '("latest-branch-revision-max-processes") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'latest-branch-revision-max-processes
                              (string->number arg)
                              result)))
        (option '("skip-system-tests") #f #f
                (lambda (opt name _ result)
                  (alist-cons 'skip-system-tests #t result)))
        (option '("per-job-parallelism") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'per-job-parallelism
                              (string->number arg)
                              result)))
        (option '("inferior-memory-limit") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'inferior-memory-limit
                              (string->number arg)
                              result)))
        (option '("inferior-set-environment-variable") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'inferior-environment-variable
                              (string-split arg #\=)
                              result)))
        (option '("free-space-requirement") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'free-space-requirement
                              (string->number arg)
                              result)))
        (option '("ignore-systems") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'ignore-systems
                              (string-split arg #\,)
                              result)))
        (option '("ignore-targets") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'ignore-targets
                              (string-split arg #\,)
                              result)))
        (option '("timeout") #t #f
                (lambda (opt name arg result)
                  (alist-cons 'timeout
                              (string->number arg)
                              result)))))


(define %default-options
  ;; Alist of default option values
  `((max-processes . ,default-max-processes)
    (per-job-parallelism . 1)
    (ignore-systems . ())
    (ignore-targets . ())
    (timeout        . ,(* (* 60 60) ;; 1 hour in seconds
                          72))))

(define (parse-options args)
  (args-fold
   args %options
   (lambda (opt name arg result)
     (error "unrecognized option" name))
   (lambda (arg result)
     (alist-cons
      'revision-commits
      (cons arg
            (or (assoc-ref result 'revision-commits)
                '()))
      (alist-delete 'revision-commits result)))
   %default-options))

(let ((opts (parse-options (cdr (program-arguments)))))
  (run-sqitch)

  (with-postgresql-connection
   "process-jobs"
   (lambda (conn)
     (simple-format #t "Ready to process jobs...\n")
     (with-exception-handler
         (lambda (exn)
           (exit 1))
       (lambda ()
         (with-exception-handler
             (lambda (exn)
               (print-backtrace-and-exception/knots exn)
               (raise-exception exn))
           (lambda ()
             (process-jobs
              conn
              #:max-processes (assq-ref opts 'max-processes)
              #:latest-branch-revision-max-processes
              (or (assq-ref opts 'latest-branch-revision-max-processes)
                  (* 2 (assq-ref opts 'max-processes)))
              #:skip-system-tests?
              (assq-ref opts 'skip-system-tests)
              #:extra-inferior-environment-variables
              (filter-map
               (match-lambda
                 (('inferior-environment-variable key val)
                  (cons key val))
                 (_ #f))
               opts)
              #:per-job-parallelism
              (assq-ref opts 'per-job-parallelism)
              #:inferior-memory-limit
              (assq-ref opts 'inferior-memory-limit)
              #:ignore-systems (assq-ref opts 'ignore-systems)
              #:ignore-targets (assq-ref opts 'ignore-targets)
              #:free-space-requirement
              (assq-ref opts 'free-space-requirement)
              #:timeout
              (assq-ref opts 'timeout)))))
       #:unwind? #t))))